I have to update all column names within an Access database of 8 tables. In a nutshell, each underscore inside a column title ought to be changed having a space. Are you able to recommend a quick way of carrying this out?

Have you use TableDefs

DatabaseName.TableDefs("TableName").Fields("FieldName").Name = "NewName"

http://msdn.microsoft.com/en-us/library/bb220949.aspx

I authored code with this to have an application just a week ago:

  Public Sub RenameFields(ByRef tdf As DAO.TableDef)
    Dim fld As DAO.Field
    Dim strFieldName As String
    Dim strNewName As String

    Debug.Print "==============================================" & vbCrLf & UCase(tdf.Name)
    For Each fld In tdf.Fields
      strFieldName = fld.Name
      strNewName = Mid(strFieldName, 4)
      Select Case Left(strFieldName, 3)
        Case "boo", "byt", "cur", "dat", "hyp", "int", "mem", "obj", "txt"
          fld.Name = strNewName
          Debug.Print tdf.Name & "." & strFieldName & "=>" & strNewName
      End Select
    Next fld
    Set fld = Nothing
  End Sub

Within this situation, an earlier developer had stupidly used VBA variable naming conventions for that area names (txtLastName for which ought to be LastName, for example) and that i required to remove these. The code is known as such as this:

  Dim tdf As DAO.TableDef

  For Each tdf in CurrentDB.TableDefs
    If Left(tdf.Name,3) = "tbl" Then ' <= this line may differ for you
       Call RenameFields(tdf)
    End If
  Next tdf
  Set tdf = Nothing

You can easily adapt the RenameFields() sub to make use of Replace() for that new title, something similar to this:

  Public Sub RenameFields(ByRef tdf As DAO.TableDef)
    Dim fld As DAO.Field
    Dim strFieldName As String
    Dim strNewName As String

    Debug.Print "==============================================" & vbCrLf & UCase(tdf.Name)
    For Each fld In tdf.Fields
      strFieldName = fld.Name
      strNewName = Replace(strFieldName, "_"," ")
      If strFieldName <> strNewName Then
         fld.Name = strNewName
         Debug.Print tdf.Name & "." & strFieldName & "=>" & strNewName
      End If
    Next fld
    Set fld = Nothing
  End Sub

All nevertheless, I'd really, really highly recommend that you simply not replace the underscores with spaces, because this causes it to be much, a lot more difficult to utilize the area names in SQL as well as in code. I'd use CAMEL situation without any underscores or spaces or dashes to ensure that the Replace() line within the code above would become:

  strNewName = Replace(StrConv(Replace(strFieldName, "_"," "), vbProper)," ", vbNullString)

That will convert "Last_Title" or "last_title" to "LastName". Camel situation for readability of area names continues to be standard for Access designers as lengthy as I have been programming in Access (since 1996), and eliminates the problems triggered by special figures or spaces (i.e., needing to surround the area title with square brackets).